awk \
'BEGIN {
    # afre = All Fields RegExp
    "tr \\\\012 \\| < field-names.txt" | getline afre;
    sub(/\|$/, "", afre);
    afre = "(^| )("afre")( |$)";
}
$0 ~ afre { print FILENAME; }
{ nextfile; }' **/*.TXT

We take the time once at the start to compute the regex for any one of all the fields looked after,
so that the main "loop" can then run at max throttle.

And as we look only in the first line, after having looked up we use a nextfile unconditionally to switch to the next input file, wether we had a match or not.

Which solution to choose?

So the difference with @anubhava 's solution (that I liked too, and voted up: for my first three bullets, which solution you choose is a matter of taste) are:

• dedicate the script to the lookup (do not mix the lookup with the regex building)
• build the regex with an external search and replace instead of a loop
• use the ^ and $ to match as the first or last field
  but I often use the additional spaces trick too
• do nextfile wether we match or not (no point in continuing reading all lines of a file whose line 1 did not match)

Further optimization

Note that depending on the implementation of awk, the $0 ~ afre may recompile the regexp at each line (because it is a variable, it can… vary, thus awk has to check it has not changed if it wants to cache the compiled version of the regex).

As you run it by shell, you can force it to a fixed regex (more easily optimizable) with an (admitedly less readable):

awk \
'/(^| )('"`tr \\\\012 \| < field-names.txt | sed -e 's/|$//'`"')( |$)/ { print FILENAME; }
{ nextfile; }' \
**/*.TXT